office365officemicrosoft365microsoftmassgravelmassgravewindows-11kms38windows-10kmswindowshwidpowershellactivatorohook
You can not select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
523 lines
19 KiB
523 lines
19 KiB
@setlocal DisableDelayedExpansion |
|
@echo off |
|
|
|
|
|
|
|
::============================================================================ |
|
:: |
|
:: This script is a part of 'Microsoft Activation Scripts' (MAS) project. |
|
:: |
|
:: Homepage: massgrave.dev |
|
:: Email: windowsaddict@protonmail.com |
|
:: |
|
::============================================================================ |
|
|
|
|
|
|
|
:: For unattended mode, run the script with /u parameter. |
|
|
|
|
|
|
|
::======================================================================================================================================== |
|
|
|
:: Re-launch the script with x64 process if it was initiated by x86 process on x64 bit Windows |
|
:: or with ARM64 process if it was initiated by x86/ARM32 process on ARM64 Windows |
|
|
|
set "_cmdf=%~f0" |
|
for %%# in (%*) do ( |
|
if /i "%%#"=="r1" set r1=1 |
|
if /i "%%#"=="r2" set r2=1 |
|
) |
|
|
|
if exist %SystemRoot%\Sysnative\cmd.exe if not defined r1 ( |
|
setlocal EnableDelayedExpansion |
|
start %SystemRoot%\Sysnative\cmd.exe /c ""!_cmdf!" %* r1" |
|
exit /b |
|
) |
|
|
|
:: Re-launch the script with ARM32 process if it was initiated by x64 process on ARM64 Windows |
|
|
|
if exist %SystemRoot%\SysArm32\cmd.exe if %PROCESSOR_ARCHITECTURE%==AMD64 if not defined r2 ( |
|
setlocal EnableDelayedExpansion |
|
start %SystemRoot%\SysArm32\cmd.exe /c ""!_cmdf!" %* r2" |
|
exit /b |
|
) |
|
|
|
:: Set Path variable, it helps if it is misconfigured in the system |
|
|
|
set "PATH=%SystemRoot%\System32;%SystemRoot%\System32\wbem;%SystemRoot%\System32\WindowsPowerShell\v1.0\" |
|
if exist "%SystemRoot%\Sysnative\reg.exe" ( |
|
set "PATH=%SystemRoot%\Sysnative;%SystemRoot%\Sysnative\wbem;%SystemRoot%\Sysnative\WindowsPowerShell\v1.0\;%PATH%" |
|
) |
|
|
|
:: Check LF line ending |
|
|
|
pushd "%~dp0" |
|
>nul findstr /rxc:".*" "%~nx0" |
|
if not %errorlevel%==0 ( |
|
echo: |
|
echo Error: This is not a correct file. It has LF line ending issue. |
|
echo: |
|
echo Press any key to exit... |
|
pause >nul |
|
popd |
|
exit /b |
|
) |
|
popd |
|
|
|
::======================================================================================================================================== |
|
|
|
cls |
|
color 07 |
|
title Install Windows Retail/OEM/MAK Key |
|
|
|
set _args= |
|
set _elev= |
|
set _unattended=0 |
|
|
|
set _args=%* |
|
if defined _args set _args=%_args:"=% |
|
if defined _args ( |
|
for %%A in (%_args%) do ( |
|
if /i "%%A"=="-el" set _elev=1 |
|
if /i "%%A"=="/u" set _unattended=1 |
|
) |
|
) |
|
|
|
::======================================================================================================================================== |
|
|
|
set winbuild=1 |
|
set "nul=>nul 2>&1" |
|
set psc=powershell.exe |
|
for /f "tokens=6 delims=[]. " %%G in ('ver') do set winbuild=%%G |
|
|
|
set _NCS=1 |
|
if %winbuild% LSS 10586 set _NCS=0 |
|
if %winbuild% GEQ 10586 reg query "HKCU\Console" /v ForceV2 2>nul | find /i "0x0" 1>nul && (set _NCS=0) |
|
|
|
if %_NCS% EQU 1 ( |
|
for /F %%a in ('echo prompt $E ^| cmd') do set "esc=%%a" |
|
set "Red="41;97m"" |
|
set "Green="42;97m"" |
|
set "_Green="40;92m"" |
|
set "_Yellow="40;93m"" |
|
) else ( |
|
set "Red="Red" "white"" |
|
set "Green="DarkGreen" "white"" |
|
set "_Green="Black" "Green"" |
|
set "_Yellow="Black" "Yellow"" |
|
) |
|
|
|
set "nceline=echo: &echo ==== ERROR ==== &echo:" |
|
set "eline=echo: &call :dk_color %Red% "==== ERROR ====" &echo:" |
|
set "line=echo ___________________________________________________________________________________________" |
|
|
|
::======================================================================================================================================== |
|
|
|
if %winbuild% LSS 10240 ( |
|
%eline% |
|
echo Unsupported OS version detected. |
|
echo Project is supported for Windows 10/11. |
|
goto ins_done |
|
) |
|
|
|
for %%# in (powershell.exe) do @if "%%~$PATH:#"=="" ( |
|
%nceline% |
|
echo Unable to find powershell.exe in the system. |
|
goto ins_done |
|
) |
|
|
|
::======================================================================================================================================== |
|
|
|
:: Fix for the special characters limitation in path name |
|
|
|
set "_work=%~dp0" |
|
if "%_work:~-1%"=="\" set "_work=%_work:~0,-1%" |
|
|
|
set "_batf=%~f0" |
|
set "_batp=%_batf:'=''%" |
|
|
|
set _PSarg="""%~f0""" -el %_args% |
|
|
|
set "_ttemp=%temp%" |
|
|
|
setlocal EnableDelayedExpansion |
|
|
|
::======================================================================================================================================== |
|
|
|
echo "!_batf!" | find /i "!_ttemp!" 1>nul && ( |
|
if /i not "!_work!"=="!_ttemp!" ( |
|
%eline% |
|
echo Script is launched from the temp folder, |
|
echo Most likely you are running the script directly from the archive file. |
|
echo: |
|
echo Extract the archive file and launch the script from the extracted folder. |
|
goto ins_done |
|
) |
|
) |
|
|
|
::======================================================================================================================================== |
|
|
|
:: Elevate script as admin and pass arguments and preventing loop |
|
|
|
%nul% reg query HKU\S-1-5-19 || ( |
|
if not defined _elev %nul% %psc% "start cmd.exe -arg '/c \"!_PSarg:'=''!\"' -verb runas" && exit /b |
|
%eline% |
|
echo This script require administrator privileges. |
|
echo To do so, right click on this script and select 'Run as administrator'. |
|
goto ins_done |
|
) |
|
|
|
::======================================================================================================================================== |
|
|
|
cls |
|
mode 98, 30 |
|
|
|
call :dk_initial |
|
|
|
:: Check product name |
|
|
|
cls |
|
call :dk_product |
|
|
|
::======================================================================================================================================== |
|
|
|
:: Check SKU value / Check in multiple places to find Edition change corruption |
|
|
|
set osSKU= |
|
set regSKU= |
|
set wmiSKU= |
|
|
|
for /f "tokens=3 delims=." %%a in ('reg query "HKLM\SYSTEM\CurrentControlSet\Control\ProductOptions" /v OSProductPfn 2^>nul') do set "regSKU=%%a" |
|
if %_wmic% EQU 1 for /f "tokens=2 delims==" %%a in ('"wmic Path Win32_OperatingSystem Get OperatingSystemSKU /format:LIST" 2^>nul') do if not errorlevel 1 set "wmiSKU=%%a" |
|
if %_wmic% EQU 0 for /f "tokens=1" %%a in ('%psc% "([WMI]'Win32_OperatingSystem=@').OperatingSystemSKU" 2^>nul') do if not errorlevel 1 set "wmiSKU=%%a" |
|
|
|
set osSKU=%wmiSKU% |
|
if not defined osSKU set osSKU=%regSKU% |
|
|
|
if not defined osSKU ( |
|
%eline% |
|
echo SKU value was not detected properly. Aborting... |
|
goto ins_done |
|
) |
|
|
|
::======================================================================================================================================== |
|
|
|
:: Detect key |
|
|
|
set key= |
|
set pkey= |
|
set _chan= |
|
|
|
if defined applist call :hwiddata attempt1 |
|
if not defined key call :hwiddata attempt2 |
|
|
|
set pkey= |
|
if not defined key call :dk_hwidkey %nul% |
|
|
|
if not defined key ( |
|
%eline% |
|
%psc% $ExecutionContext.SessionState.LanguageMode 2>nul | find /i "Full" 1>nul || ( |
|
echo PowerShell is not responding properly. |
|
echo: |
|
) |
|
echo Unable to find HWID key for [%winos% ^| SKU:%osSKU% ^| %winbuild%] |
|
echo Make sure you are using updated version of the script |
|
echo: |
|
if not "%regSKU%"=="%wmiSKU%" ( |
|
echo Difference Found In SKU Value- WMI:%wmiSKU% Reg:%regSKU% |
|
echo Restart the system and try again. |
|
) |
|
goto ins_done |
|
) |
|
|
|
if defined key call :dk_pkeychannel %key% |
|
if defined pkeychannel set _chan=%pkeychannel% Key |
|
|
|
::======================================================================================================================================== |
|
|
|
if %_unattended%==1 goto insertkey |
|
|
|
cls |
|
%line% |
|
echo: |
|
echo Install [%winos% ^| SKU:%osSKU% ^| %winbuild%] %_chan% |
|
echo [%key%] |
|
%line% |
|
echo: |
|
if not "%regSKU%"=="%wmiSKU%" ( |
|
echo Note: Difference Found In SKU Value- WMI:%wmiSKU% Reg:%regSKU% |
|
echo Restart the system to resolve it |
|
echo: |
|
) |
|
call :dk_color %_Green% "Press [1] to Continue or [2] to Exit" |
|
choice /C:21 /N |
|
if %errorlevel%==1 exit /b |
|
cls |
|
|
|
::======================================================================================================================================== |
|
|
|
:insertkey |
|
|
|
cls |
|
%line% |
|
|
|
if %_wmic% EQU 1 wmic path SoftwareLicensingService where __CLASS='SoftwareLicensingService' call InstallProductKey ProductKey="%key%" %nul% |
|
if %_wmic% EQU 0 %psc% "(([WMISEARCHER]'SELECT Version FROM SoftwareLicensingService').Get()).InstallProductKey('%key%')" %nul% |
|
if not %errorlevel%==0 cscript //nologo %windir%\system32\slmgr.vbs /ipk %key% %nul% |
|
|
|
set error_code=%errorlevel% |
|
cmd /c exit /b %error_code% |
|
if %error_code% NEQ 0 set "error_code=[0x%=ExitCode%]" |
|
|
|
if %error_code% EQU 0 ( |
|
call :dk_refresh |
|
echo: |
|
echo [%winos% ^| SKU:%osSKU% ^| %winbuild%] |
|
echo Installing %_chan% [%key%] |
|
echo: |
|
call :dk_color %Green% "[Successful]" |
|
) else ( |
|
%eline% |
|
echo [%winos% ^| SKU:%osSKU% ^| %winbuild%] |
|
echo Installing %_chan% [%key%] |
|
echo: |
|
call :dk_color %Red% "[Unsuccessful] %error_code%" |
|
if not defined applist echo Not Respoding: %e_wmispp% |
|
) |
|
%line% |
|
|
|
::======================================================================================================================================== |
|
|
|
:ins_done |
|
|
|
echo: |
|
if %_unattended%==1 timeout /t 2 & exit /b |
|
call :dk_color %_Yellow% "Press any key to exit..." |
|
pause >nul |
|
exit /b |
|
|
|
::======================================================================================================================================== |
|
|
|
:: Refresh license status |
|
|
|
:dk_refresh |
|
|
|
if %_wmic% EQU 1 wmic path SoftwareLicensingService where __CLASS='SoftwareLicensingService' call RefreshLicenseStatus %nul% |
|
if %_wmic% EQU 0 %psc% "$null=(([WMICLASS]'SoftwareLicensingService').GetInstances()).RefreshLicenseStatus()" %nul% |
|
exit /b |
|
|
|
:: Get Windows Activation IDs |
|
|
|
:dk_actids |
|
|
|
set applist= |
|
if %_wmic% EQU 1 set "chkapp=for /f "tokens=2 delims==" %%a in ('"wmic path SoftwareLicensingProduct where (ApplicationID='55c92734-d682-4d71-983e-d6ec3f16059f') get ID /VALUE" 2^>nul')" |
|
if %_wmic% EQU 0 set "chkapp=for /f "tokens=2 delims==" %%a in ('%psc% "(([WMISEARCHER]'SELECT ID FROM SoftwareLicensingProduct WHERE ApplicationID=''55c92734-d682-4d71-983e-d6ec3f16059f''').Get()).ID ^| %% {echo ('ID='+$_)}" 2^>nul')" |
|
%chkapp% do (if defined applist (call set "applist=!applist! %%a") else (call set "applist=%%a")) |
|
exit /b |
|
|
|
:: Get Product name (WMI/REG methods are not reliable in all conditions, hence winbrand.dll method is used) |
|
|
|
:dk_product |
|
|
|
set winos= |
|
set d1=[DllImport(\"winbrand\",CharSet=CharSet.Unicode)]public static extern string BrandingFormatString(string s); |
|
set d2=$AP=Add-Type -Member '%d1%' -Name D1 -PassThru; $AP::BrandingFormatString('%%WINDOWS_LONG%%') |
|
for /f "delims=" %%s in ('"%psc% %d2%"') do if not errorlevel 1 (set winos=%%s) |
|
echo "%winos%" | find /i "Windows" 1>nul || ( |
|
for /f "skip=2 tokens=2*" %%a in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v ProductName 2^>nul') do set "winos=%%b" |
|
if %winbuild% GEQ 22000 ( |
|
set winos=!winos:Windows 10=Windows 11! |
|
) |
|
) |
|
exit /b |
|
|
|
:: Check wmic.exe |
|
|
|
:dk_ckeckwmic |
|
|
|
set _wmic=0 |
|
for %%# in (wmic.exe) do @if not "%%~$PATH:#"=="" ( |
|
wmic path Win32_ComputerSystem get CreationClassName /value 2>nul | find /i "computersystem" 1>nul && set _wmic=1 |
|
) |
|
exit /b |
|
|
|
:dk_initial |
|
|
|
echo: |
|
echo Initializing... |
|
|
|
:: Check and enable WinMgmt, sppsvc services if required |
|
|
|
for %%# in (WinMgmt sppsvc) do ( |
|
for /f "skip=2 tokens=2*" %%a in ('reg query HKLM\SYSTEM\CurrentControlSet\Services\%%# /v Start 2^>nul') do if /i %%b NEQ 0x2 ( |
|
echo: |
|
echo Enabling %%# service... |
|
if /i %%#==sppsvc sc config %%# start= delayed-auto %nul% || echo Failed |
|
if /i %%#==WinMgmt sc config %%# start= auto %nul% || echo Failed |
|
) |
|
sc start %%# %nul% |
|
if !errorlevel! NEQ 1056 if !errorlevel! NEQ 0 ( |
|
echo: |
|
echo Starting %%# service... |
|
sc start %%# |
|
echo: |
|
call :dk_color %Red% "Failed to start [%%#] service, rest of the process may take a long time..." |
|
) |
|
) |
|
|
|
:: Check WMI and SPP Errors |
|
|
|
call :dk_ckeckwmic |
|
|
|
set e_wmi= |
|
set e_wmispp= |
|
call :dk_actids |
|
|
|
if not defined applist ( |
|
net stop sppsvc /y %nul% |
|
cscript //nologo %windir%\system32\slmgr.vbs /rilc %nul% |
|
if !errorlevel! NEQ 0 cscript //nologo %windir%\system32\slmgr.vbs /rilc %nul% |
|
call :dk_refresh |
|
|
|
if %_wmic% EQU 1 wmic path Win32_ComputerSystem get CreationClassName /value 2>nul | find /i "computersystem" 1>nul |
|
if %_wmic% EQU 0 %psc% "Get-CIMInstance -Class Win32_ComputerSystem | Select-Object -Property CreationClassName" 2>nul | find /i "computersystem" 1>nul |
|
if !errorlevel! NEQ 0 set e_wmi=1 |
|
|
|
if defined e_wmi (set e_wmispp=WMI, SPP) else (set e_wmispp=SPP) |
|
call :dk_actids |
|
) |
|
exit /b |
|
|
|
::======================================================================================================================================== |
|
|
|
:: Get Product Key from pkeyhelper.dll for future new editions |
|
:: It works on Windows 10 1803 (17134) and later builds. (Partially on 1803 & 1809, fully on 1903 and later) |
|
|
|
:dk_pkey |
|
|
|
set pkey= |
|
set d1=[DllImport(\"pkeyhelper.dll\",CharSet=CharSet.Unicode)]public static extern int SkuGetProductKeyForEdition(int e, string c, out string k, out string p); |
|
set d2=$AP=Add-Type -Member '%d1%' -Name D1 -PassThru; $k=''; $null=$AP::SkuGetProductKeyForEdition(%1, %2, [ref]$k, [ref]$null); $k |
|
for /f %%a in ('%psc% "%d2%"') do if not errorlevel 1 (set pkey=%%a) |
|
exit /b |
|
|
|
:: Get channel name for the key which was extracted from pkeyhelper.dll |
|
|
|
:dk_pkeychannel |
|
|
|
set k=%1 |
|
set pkeychannel= |
|
set p=%SystemRoot%\System32\spp\tokens\pkeyconfig\pkeyconfig.xrm-ms |
|
set m=[System.Runtime.InteropServices.Marshal] |
|
set d1=[DllImport(\"PidGenX.dll\",CharSet=CharSet.Unicode)]public static extern int PidGenX(string k,string p,string m,int u,IntPtr i,IntPtr d,IntPtr f); |
|
set d2=$AP=Add-Type -Member '%d1%' -Name D1 -PassThru; $k='%k%'; $p='%p%'; $r=[byte[]]::new(0x04F8); $r[0]=0xF8; $r[1]=0x04; $f=%m%::AllocHGlobal(1272); %m%::Copy($r,0,$f,1272); |
|
set d3=%d2% [void]$AP::PidGenX($k,$p,\"00000\",0,0,0,$f); %m%::Copy($f,$r,0,1272); %m%::FreeHGlobal($f); [System.Text.Encoding]::Unicode.GetString($r, 1016, 128).Replace('0','') |
|
for /f %%a in ('%psc% "%d3%"') do if not errorlevel 1 (set pkeychannel=%%a) |
|
exit /b |
|
|
|
:dk_hwidkey |
|
|
|
for %%# in (pkeyhelper.dll) do @if "%%~$PATH:#"=="" exit /b |
|
for %%# in (Retail OEM:NONSLP OEM:DM Volume:MAK) do ( |
|
call :dk_pkey %osSKU% '%%#' |
|
if defined pkey call :dk_pkeychannel !pkey! |
|
if /i [!pkeychannel!]==[%%#] ( |
|
set key=!pkey! |
|
exit /b |
|
) |
|
) |
|
exit /b |
|
|
|
::======================================================================================================================================== |
|
|
|
:dk_color |
|
|
|
if %_NCS% EQU 1 ( |
|
echo %esc%[%~1%~2%esc%[0m |
|
) else ( |
|
%psc% write-host -back '%1' -fore '%2' '%3' |
|
) |
|
exit /b |
|
|
|
::======================================================================================================================================== |
|
|
|
:: 1st column = Activation ID |
|
:: 2nd column = Generic Retail/OEM/MAK Key |
|
:: 3rd column = SKU ID |
|
:: 4th column = 1 = activation is not working (at the time of writing this), 0 = activation is working |
|
:: 5th column = Key Type |
|
:: 6th column = WMI Edition ID |
|
:: 7th column = Version name incase same Edition ID is used in different OS versions with different key |
|
:: Separator = _ |
|
|
|
:: Key preference is in the following order. Retail > OEM:NONSLP > OEM:DM > Volume:MAK |
|
|
|
|
|
:hwiddata |
|
|
|
for %%# in ( |
|
8b351c9c-f398-4515-9900-09df49427262_XGVPP-NMH47-7TTHJ-W3FW7-8HV2C___4_0_OEM:NONSLP_Enterprise |
|
23505d51-32d6-41f0-8ca7-e78ad0f16e71_D6RD9-D4N8T-RT9QX-YW6YT-FCWWJ__11_1_____Retail_Starter |
|
c83cef07-6b72-4bbc-a28f-a00386872839_3V6Q6-NQXCX-V8YXR-9QCYV-QPFCT__27_0_Volume:MAK_EnterpriseN |
|
211b80cc-7f64-482c-89e9-4ba21ff827ad_3NFXW-2T27M-2BDW6-4GHRV-68XRX__47_1_____Retail_StarterN |
|
4de7cb65-cdf1-4de9-8ae8-e3cce27b9f2c_VK7JG-NPHTM-C97JM-9MPGT-3V66T__48_0_____Retail_Professional |
|
9fbaf5d6-4d83-4422-870d-fdda6e5858aa_2B87N-8KFHP-DKV6R-Y2C8J-PKCKT__49_0_____Retail_ProfessionalN |
|
f742e4ff-909d-4fe9-aacb-3231d24a0c58_4CPRK-NM3K3-X6XXQ-RXX86-WXCHW__98_0_____Retail_CoreN |
|
1d1bac85-7365-4fea-949a-96978ec91ae0_N2434-X9D7W-8PF6X-8DV9T-8TYMD__99_0_____Retail_CoreCountrySpecific |
|
3ae2cc14-ab2d-41f4-972f-5e20142771dc_BT79Q-G7N6G-PGBYW-4YWX6-6F4BT_100_0_____Retail_CoreSingleLanguage |
|
2b1f36bb-c1cd-4306-bf5c-a0367c2d97d8_YTMG3-N6DKC-DKB77-7M9GH-8HVX7_101_0_____Retail_Core |
|
2a6137f3-75c0-4f26-8e3e-d83d802865a4_XKCNC-J26Q9-KFHD2-FKTHY-KD72Y_119_0_OEM:NONSLP_PPIPro |
|
e558417a-5123-4f6f-91e7-385c1c7ca9d4_YNMGQ-8RYV3-4PGQ3-C8XTP-7CFBY_121_0_____Retail_Education |
|
c5198a66-e435-4432-89cf-ec777c9d0352_84NGF-MHBT6-FXBX8-QWJK7-DRR8H_122_0_____Retail_EducationN |
|
cce9d2de-98ee-4ce2-8113-222620c64a27_KCNVH-YKWX8-GJJB9-H9FDT-6F7W2_125_1_Volume:MAK_EnterpriseS_2021 |
|
d06934ee-5448-4fd1-964a-cd077618aa06_43TBQ-NH92J-XKTM7-KT3KK-P39PB_125_0_OEM:NONSLP_EnterpriseS_2019 |
|
706e0cfd-23f4-43bb-a9af-1a492b9f1302_NK96Y-D9CD8-W44CQ-R8YTK-DYJWX_125_0_OEM:NONSLP_EnterpriseS_2016 |
|
faa57748-75c8-40a2-b851-71ce92aa8b45_FWN7H-PF93Q-4GGP8-M8RF3-MDWWW_125_0_OEM:NONSLP_EnterpriseS_2015 |
|
2c060131-0e43-4e01-adc1-cf5ad1100da8_RQFNW-9TPM3-JQ73T-QV4VQ-DV9PT_126_1_Volume:MAK_EnterpriseSN_2021 |
|
e8f74caa-03fb-4839-8bcc-2e442b317e53_M33WV-NHY3C-R7FPM-BQGPT-239PG_126_1_Volume:MAK_EnterpriseSN_2019 |
|
3d1022d8-969f-4222-b54b-327f5a5af4c9_2DBW3-N2PJG-MVHW3-G7TDK-9HKR4_126_0_Volume:MAK_EnterpriseSN_2016 |
|
60c243e1-f90b-4a1b-ba89-387294948fb6_NTX6B-BRYC2-K6786-F6MVQ-M7V2X_126_0_Volume:MAK_EnterpriseSN_2015 |
|
a48938aa-62fa-4966-9d44-9f04da3f72f2_G3KNM-CHG6T-R36X3-9QDG6-8M8K9_138_1_____Retail_ProfessionalSingleLanguage |
|
f7af7d09-40e4-419c-a49b-eae366689ebd_HNGCC-Y38KG-QVK8D-WMWRK-X86VK_139_1_____Retail_ProfessionalCountrySpecific |
|
eb6d346f-1c60-4643-b960-40ec31596c45_DXG7C-N36C4-C4HTG-X4T3X-2YV77_161_0_____Retail_ProfessionalWorkstation |
|
89e87510-ba92-45f6-8329-3afa905e3e83_WYPNQ-8C467-V2W6J-TX4WX-WT2RQ_162_0_____Retail_ProfessionalWorkstationN |
|
62f0c100-9c53-4e02-b886-a3528ddfe7f6_8PTT6-RNW4C-6V7J2-C2D3X-MHBPB_164_0_____Retail_ProfessionalEducation |
|
13a38698-4a49-4b9e-8e83-98fe51110953_GJTYN-HDMQY-FRR76-HVGC7-QPF8P_165_0_____Retail_ProfessionalEducationN |
|
1ca0bfa8-d96b-4815-a732-7756f30c29e2_FV469-WGNG4-YQP66-2B2HY-KD8YX_171_1_OEM:NONSLP_EnterpriseG |
|
8d6f6ffe-0c30-40ec-9db2-aad7b23bb6e3_FW7NV-4T673-HF4VX-9X4MM-B4H4T_172_1_OEM:NONSLP_EnterpriseGN |
|
df96023b-dcd9-4be2-afa0-c6c871159ebe_NJCF7-PW8QT-3324D-688JX-2YV66_175_0_____Retail_ServerRdsh |
|
d4ef7282-3d2c-4cf0-9976-8854e64a8d1e_V3WVW-N2PV2-CGWC3-34QGF-VMJ2C_178_0_____Retail_Cloud |
|
af5c9381-9240-417d-8d35-eb40cd03e484_NH9J3-68WK7-6FB93-4K3DF-DJ4F6_179_0_____Retail_CloudN |
|
c7051f63-3a76-4992-bce5-731ec0b1e825_2HN6V-HGTM8-6C97C-RK67V-JQPFD_183_1_____Retail_CloudE |
|
8ab9bdd1-1f67-4997-82d9-8878520837d9_XQQYW-NFFMW-XJPBH-K8732-CKFFD_188_0_____OEM:DM_IoTEnterprise |
|
ed655016-a9e8-4434-95d9-4345352c2552_QPM6N-7J2WJ-P88HH-P3YRH-YY74H_191_0_OEM:NONSLP_IoTEnterpriseS |
|
d4bdc678-0a4b-4a32-a5b3-aaa24c3b0f24_K9VKN-3BGWV-Y624W-MCRMQ-BHDCD_202_0_____Retail_CloudEditionN |
|
92fb8726-92a8-4ffc-94ce-f82e07444653_KY7PN-VR6RX-83W6Y-6DDYQ-T6R4W_203_0_____Retail_CloudEdition |
|
) do ( |
|
for /f "tokens=1-8 delims=_" %%A in ("%%#") do if %osSKU%==%%C ( |
|
|
|
if %1==attempt1 if not defined key ( |
|
echo "!applist!" | find /i "%%A" 1>nul && ( |
|
set key=%%B |
|
) |
|
) |
|
|
|
if %1==attempt2 if not defined key ( |
|
set 7th=%%G |
|
if not defined 7th ( |
|
if %winbuild% GTR 19044 call :dk_hwidkey %nul% |
|
if not defined key set key=%%B |
|
) else ( |
|
echo "%winos%" | find /i "%%G" 1>nul && ( |
|
if %winbuild% GTR 19044 call :dk_hwidkey %nul% |
|
if not defined key set key=%%B |
|
) |
|
) |
|
) |
|
) |
|
) |
|
exit /b |
|
|
|
::======================================================================================================================================== |